3.3 フォルダの中を下の階層まで探る
　フォルダに入っている全てのファイルの情報を得るときの方法です。もちろん、下の階層に入っているファイルも全て検索し、全ファイルの合計サイズやファイル数、フォルダ数まで取得する方法です。
使用例
　使用するオブジェクトやメソッドは基本的に3.2 フォルダの中を探ると同じです。

　大きく違う部分は、フォルダの内容を探る部分(For ～ Next)をSubプロシジャ(prcFolderSize)にした所と、フォルダアイテムオブジェクトから取り出したアイテムがフォルダだったときに、そのアイテムをGetFolderメソッドでフォルダオブジェクトに変え、さらにそこからItemsメソッドでフォルダアイテムオブジェクトを取り出し、そして、そのフォルダにさらに探りを入れるために、取り出したフォルダアイテムオブジェクトをパラメタとして、さらにprcFolderSizeを呼び出している所。
　このようにすると、検索の先頭になるフォルダ以下の全てのフォルダに探りを入れることが可能です。ちなみに、自分自身をさらに呼び出すことを再帰呼び出しといいます。

　再帰呼び出しで処理を行うことにより、いずれは先頭のフォルダ以降の全てのファイルとフォルダが処理されるので、ファイルの時はサイズと個数の集計、フォルダのときは個数の集計（もちろん、そのフォルダの探りも）を行えば、総容量や総ファイル数を取得できます。

　でも、なぜか特定のファイル（拡張子がvxdなど）の情報だけ取れないのです。情報が取れないと言うより、最初からアイテムとして入ってこないんですよ（泣）。なぜなのでしょう…だから「約xxxバイト」なのです（汗）

　■VBScriptの記述例
Option Explicit

Dim objApl
Dim objFolder
Dim objFolderItems
Dim numFolderSize
Dim numFileCount
Dim numFolderCount

numFolderSize=0
numFileCount=0
numFolderCount=0

'①シェルアプリケーションオブジェクトを作成します
Set objApl = WScript.CreateObject("Shell.Application")

'②探りを入れたいフォルダのオブジェクトを作成します
Set objFolder = objApl.NameSpace("C:\happy")

'③フォルダオブジェクトから、入っているファイルや
'　フォルダの情報を取得します
Set objFolderItems = objFolder.Items()

'フォルダの検索処理の呼び出し
Call prcFolderSize (objFolderItems)

'結果の表示。総容量、総ファイル数、総フォルダ数を表示
WScript.Echo "フォルダC:\happyの容量は、約" & numFolderSize & "バイトです"
WScript.Echo "フォルダC:\happyのファイル数は、約" & numFileCount & "個です"
WScript.Echo "フォルダC:\happyのフォルダ数は、約" & numFolderCount & "個です"

Set objFolderItems = Nothing
Set objFolder = Nothing
Set objApl = Nothing

'==============================================================
'= フォルダ内に含まれるファイルやフォルダを検索する
'==============================================================
Sub prcFolderSize(tmpFolderItems)

    Dim objFolderItemsB
    Dim objItem
    Dim i

    '④何個入っていたかは、Countで参照
    For i=0 To tmpFolderItems.Count-1

        '⑤ファイルやフォルダの情報を１コ取り出します
        Set objItem = tmpFolderItems.Item(i)

        '⑥取り出した物がファイルかフォルダかを判定
        If objItem.IsFolder Then
           '⑦フォルダであれば、フォルダアイテムオブジェクトを
           '　作り、それを引数としてprcFolderSizeを再帰呼び出します
           Set objFolderItemsB = objItem.GetFolder
           Call prcFolderSize (objFolderItemsB.Items())
           numFolderCount = numFolderCount + 1
        Else
           '⑧ファイルの場合は、サイズとファイル数を集計します
           numFolderSize = numFolderSize + objItem.Size
           numFileCount = numFileCount + 1
        End If

    Next

    Set objItem = Nothing
    Set objFolderItemsB = Nothing

End Sub

　■JScript(JavaScript)の記述例
var objApl;
var objFolder;
var objFolderItems;
var numFolderSize;
var numFileCount;
var numFolderCount;

numFolderSize=0;
numFileCount=0;
numFolderCount=0;

//①シェルアプリケーションオブジェクトを作成します
objApl = WScript.CreateObject("Shell.Application");

//②探りを入れたいフォルダのオブジェクトを作成します
objFolder = objApl.NameSpace("C:\\happy");

//③フォルダオブジェクトから、入っているファイルや
//　フォルダの情報を取得します
objFolderItems = objFolder.Items();

//フォルダの検索処理の呼び出し
prcFolderSize(objFolderItems);

//結果の表示。総容量、総ファイル数、総フォルダ数を表示
WScript.echo("フォルダC:\\happyの容量は、約" + numFolderSize + "バイトです");
WScript.echo("フォルダC:\\happyのファイル数は、約" + numFileCount + "個です");
WScript.echo("フォルダC:\\happyのフォルダ数は、約" + numFolderCount + "個です");

objFolderItems = null;
objFolder = null;
objApl = null;

//==============================================================
//= フォルダ内に含まれるファイルやフォルダを検索する
//==============================================================
function prcFolderSize(tmpFolderItems) {

    var objFolderItemsB;
    var objItem;
    var i;

    //④何個入っていたかは、Countで参照
    for (i=0;i
        //⑤ファイルやフォルダの情報を１コ取り出します
        objItem = tmpFolderItems.Item(i);

        //⑥取り出した物がファイルかフォルダかを判定
        if (objItem.IsFolder==true) {
           //⑦フォルダであれば、フォルダアイテムオブジェクトを
           //　作り、それを引数としてprcFolderSizeを再帰呼び出します
           objFolderItemsB = objItem.GetFolder;
           prcFolderSize(objFolderItemsB.Items());
           numFolderCount++;
        } else {
           //⑧ファイルの場合は、サイズとファイル数を集計します
           numFolderSize+=objItem.Size;
           numFileCount++;
        }

    }

    objItem = null;
    objFolderItemsB = null;

}
[PR]結城圭介。が書いたVBS(WSH)の本
■最速攻略 VBScriptサンプル大全集
◆最速攻略 Excel VBA サンプル大全集
（アマゾンへジャンプします）
VBScript&JScript Tips
■ファイル・フォルダ操作編
2.Scripting.FileSystemObject
   2.1 ファイルシステムオブジェクトが基本
  2.2 パスを編集する
  2.3 フォルダを新たに作る
  2.4 テキストファイルを新たに作る
  2.5 テキストファイルの行単位の読み込み
     ・他にエラー回避、Subプロシジャ
   2.6 テキストファイルの一括読み込み
  2.7 テキストファイルへの書きこみ
  2.8 フォルダやファイルのコピー
  2.9 フォルダやファイルの移動
     ・応用技でファイルやフォルダ名の変更
   2.10 フォルダやファイルの削除
  2.11 フォルダやファイルの有無を調べる
     ・他に中間ファイル(フォルダ)の作成
   2.12 ファイルの情報を見る
     ・サイズ、ファイルの種類、更新日など
   2.13 フォルダの情報を見る
     ・サイズ、更新日など
3.Shell.Application
   3.1 シェルアプリケーションオブジェクト
  3.2 フォルダの中を探る
     ・他にファイルかフォルダかの判定
   3.3 フォルダの中を下の階層まで探る
     ・フォルダ容量やファイル数を取得
      ・プロシジャの再帰呼び出し
■基本編
■ファイル・フォルダ操作編
■Excel & Access操作編
■インターネットエクスプローラ操作編
■データアクセス編
Happy! Happy! Islandその他のコンテンツ
■VBAプログラミング、その他
 　Access VBAプログラミング＆Tips
　Excel VBA(エクセルマクロ)プログラミング＆Tips
　VBScript＆JScriptプログラミング＆Tips for WSH
　プログラミング基礎・入門
　HTMLの書き方
■ダウンロードコーナー
 　AccessとExcelのフリーソフト
■コミュニティー
 　VBA質問掲示板
■その他
 　オレの話を聞けぇ♪（仮称／コラム）
　管理人プロフィール
　管理人へメール
■別館(海外向けサイト)
 　SAMURAI Game Center - Freeware games for Microsoft ACCESS and EXCEL!
VBAプログラミング＆Tips集の
"Happy! Happy! Island"トップページへ
[リンク]IT関連情報サイトなど
gihyo.jp
技術評論社提供のIT関連コンテンツサイト
モーグ
スキルアップ・問題解決はモーグにおまかせ！
[リンク]一番クリックした国が優勝
ClickClickClick.com
クリッカー＆認証人募集！日本を1位にしよう！もちろん、おいらも参加中！各種情報の入手はClickJapanオフィシャルサイトで。
[PR]証券会社・投資運用関連サイト
カブドットコム証券
逆指値・W指値等の自動売買でリスク管理追求型の投資が可能！引け後のIRやニュースを見てからでも間に合う夜間取引も魅力！
マネックス証券
オンライントレード・自動売買の最先端！「逆指値・ツイン指値」でリスクコントロール！デイトレードなら片道手数料無料！
Ｅ＊トレード証券
オンライン専業証券№１の口座数！業界最低水準の手数料体系と充実のサービスラインナップ！
楽天証券のマーケットスピード
ネット証券最強のトレーディングツール「マーケットスピード」でプロ水準の投資環境がご自宅のパソコンに！
オンライン証券徹底比較
価格．ｃｏｍで証券徹底比較！手数料、取引商品、信用取引金利、逆指値などの注文方法や提供情報などを徹底比較！
Copyright(C) 1999-2006 結城圭介。 All rights reserved